Um preset de CMake e toolchain-file para compilação cruzada para armv5-linux-musl

Setup reutilizável para compilar cruzado um projeto C++ para um binário musl ARMv5 totalmente estático (por exemplo para contêineres MikroTik EN7562CT que só rodam arm32v5). Usa o toolchain armv5l-linux-musleabi do musl.cc (GCC 11.2.1) extraído em ~/opt.

Toolchain file

cmake/toolchain-armv5l-musl.cmake
# Cross toolchain: Linux ARMv5TE soft-float (armel), musl libc, fully static.
set(CMAKE_SYSTEM_NAME Linux)
set(CMAKE_SYSTEM_PROCESSOR arm)

set(_TC "$ENV{HOME}/opt/armv5l-linux-musleabi-cross/bin/armv5l-linux-musleabi-")
set(CMAKE_C_COMPILER   "${_TC}gcc")
set(CMAKE_CXX_COMPILER "${_TC}g++")
set(CMAKE_AR           "${_TC}ar")
set(CMAKE_RANLIB       "${_TC}ranlib")

set(CMAKE_C_FLAGS_INIT   "-march=armv5te -mfloat-abi=soft")
set(CMAKE_CXX_FLAGS_INIT "-march=armv5te -mfloat-abi=soft")
# Fully static so the binary runs in any container (no musl loader needed).
set(CMAKE_EXE_LINKER_FLAGS_INIT "-static")
set(CMAKE_SHARED_LINKER_FLAGS_INIT "-static")
# ARMv5 lacks 8-byte atomic instructions; GCC emits __atomic_*_8 libcalls that
# live in libatomic. STANDARD_LIBRARIES appends it at the end of the link line
# (after the static libs that reference it), which is required for resolution.
set(CMAKE_C_STANDARD_LIBRARIES "-latomic")
set(CMAKE_CXX_STANDARD_LIBRARIES "-latomic")

set(CMAKE_FIND_ROOT_PATH_MODE_PROGRAM NEVER)
set(CMAKE_FIND_ROOT_PATH_MODE_LIBRARY ONLY)
set(CMAKE_FIND_ROOT_PATH_MODE_INCLUDE ONLY)
set(CMAKE_FIND_ROOT_PATH_MODE_PACKAGE ONLY)

Preset

CMakePresets.json
{
    "name": "arm32v5",
    "displayName": "ARMv5 musl static (EN7562CT/MikroTik containers)",
    "binaryDir": "${sourceDir}/build-arm32v5",
    "toolchainFile": "${sourceDir}/cmake/toolchain-armv5l-musl.cmake",
    "cacheVariables": {
        "CMAKE_BUILD_TYPE": "Release",
        "BUILD_SHARED_LIBS": "OFF",
        "TETHER_BUILD_STATIC_LIBS": "ON",
        "TETHER_BUILD_TESTS": "OFF",
        "TETHER_BUILD_PYTHON_BINDINGS": "OFF"
    }
}

mais uma entrada buildPresets correspondente ("configurePreset": "arm32v5").

Compilar + verificar

build.sh
cmake --preset arm32v5
cmake --build --preset arm32v5 --target list_slaves -j8
file build-arm32v5/bin/list_slaves
# ELF 32-bit LSB pie executable, ARM, EABI5, static-pie linked

Notas

  • Atenção a GCC antigo: GCC 11 não tem <format> (GCC 13+), <print> (GCC 15+) nem <expected> (GCC 12+) — uma base de código C++23 precisa de headers shim/polyfill ({fmt}, tl::expected) integrados no include path.
  • check_include_file_cxx no CMake roda contra o compilador cruzado — bom, a detecção de headers reflete o toolchain real.
  • CMAKE_<LANG>_STANDARD_LIBRARIES (não CMAKE_EXE_LINKER_FLAGS) é o lugar correto para -latomic — a ordem de linkagem importa.

Check out similar posts by category: CMake C/C++ Embarcado